3.6. Wat is het gemiddeld bruto jaarsalaris per fte?

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Grootboekpost
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• heeft deel
• heeft meeteenheid

Eigenschappen

• einddatum
• heeft datawaarde
• heeft datum
• heeftGeldBedrag
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.6
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11PREFIX time: <http://www.w3.org/2006/time#>
12
13
14SELECT 	
15	("Totaal organisatie" AS ?Indeling)
16    (ROUND(?teller * 100) / 100 AS ?Totaal_bruto_jaarsalaris)
17    (ROUND(?noemer * 100) / 100 AS ?Gewogen_fte)
18    (ROUND((?teller / ?noemer) * 100) / 100 AS ?Gemiddeld_bruto_jaarsalaris_per_fte)
19
20WHERE 
21{
22    {
23    SELECT ( SUM(?geld_bedrag) AS ?teller ) 
24    WHERE 
25    {
26     #BIND(2024 AS ?jaar)
27	 BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
28     BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode) 
29        VALUES ?rubriek { 
30            onz-fin:WPerSol
31            onz-fin:WPerLes
32            
33            onz-fin:411000
34            onz-fin:411100
35            onz-fin:411200
36            onz-fin:411300
37            onz-fin:411400
38            onz-fin:411500
39            onz-fin:411600
40            onz-fin:411700
41            onz-fin:412000
42            onz-fin:412100
43            onz-fin:412200
44            onz-fin:412300
45            onz-fin:412400
46            onz-fin:412500
47            onz-fin:413000
48            onz-fin:413100
49            onz-fin:413200
50            onz-fin:413300
51            onz-fin:413400
52            onz-fin:413500
53            onz-fin:413600
54            onz-fin:413610
55            onz-fin:413620
56            onz-fin:413700
57            onz-fin:414000
58            onz-fin:414100
59            onz-fin:414101
60            onz-fin:414102
61            onz-fin:414103
62            onz-fin:414104
63            onz-fin:414110
64            onz-fin:414111
65            onz-fin:414112
66            onz-fin:414113
67            onz-fin:414114
68            onz-fin:414200
69            onz-fin:414202
70            onz-fin:414203
71            onz-fin:414204
72            onz-fin:414300
73            onz-fin:414500
74            onz-fin:414503
75            onz-fin:414504
76            onz-fin:414700
77            onz-fin:414800
78            onz-fin:415000
79            onz-fin:422100
80            onz-fin:422300
81            onz-fin:422400
82            onz-fin:422410
83            onz-fin:422500
84            onz-fin:422600
85            onz-fin:422900
86            }
87            ?post onz-g:partOf ?rubriek .   
88
89        ?post a onz-fin:Grootboekpost ;
90            onz-g:hasDate ?datum ;
91            onz-fin:heeftGeldBedrag ?geld_bedrag .
92
93        FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
94        }
95    }
96    {
97    SELECT (SUM(?subtotaal) as ?noemer)
98    WHERE 
99        {
100        SELECT (SUM(?omvang_factor_corr) as ?subtotaal)
101        WHERE
102        { 
103            # definieer periode waarin overeenkomst geldig moet zijn
104            #BIND(2024 AS ?jaar)
105	        BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
106            BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode) 
107
108            # Selecteer alle personeelsleden met een overeenkomst binnen de meetperiode
109            ?overeenkomst 
110                a onz-pers:ArbeidsOvereenkomst ;
111                onz-g:hasPart ?overeenkomst_afspraak . 
112            ?overeenkomst_afspraak
113                a onz-pers:WerkOvereenkomstAfspraak ;                     
114                onz-g:startDatum ?start_overeenkomst .
115            OPTIONAL {?overeenkomst_afspraak onz-g:eindDatum ?eind_overeenkomst }
116            FILTER (?start_overeenkomst <= ?eindperiode && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?startperiode))
117            ?overeenkomst_afspraak onz-g:hasPart ?omvang .  
118            ?omvang
119                a onz-pers:ContractOmvang ;
120                onz-g:isAbout ?omvang_waarde .
121            ?omvang_waarde
122                a onz-pers:ContractOmvangWaarde ;
123                onz-g:hasDataValue ?omvang_waarde_getal ;
124                onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
125            ?omvang_waarde_eenheid onz-g:hasDataValue ?omvang_eenheid_factor .  
126            BIND(?omvang_waarde_getal/(36/?omvang_eenheid_factor) AS ?ptf)
127            
128            # corrigeer wanneer start of eind van de contractomvang buiten de gevraagde periode valt
129            BIND(IF(?startperiode > ?start_overeenkomst, ?startperiode, ?start_overeenkomst) AS ?start_overeenkomst_corr)
130            BIND(IF(?eindperiode < ?eind_overeenkomst || !BOUND(?eind_overeenkomst), ?eindperiode, ?eind_overeenkomst) AS ?eind_overeenkomst_corr)
131            
132            # bereken aantal dagen in de periode
133            ?startperiode ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?startperiode_reken .
134            ?eindperiode ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eindperiode_reken .
135            BIND(?eindperiode_reken - ?startperiode_reken + 1 AS ?dagen_periode)
136            
137            # bereken aantal dagen overeenkomst
138            ?start_overeenkomst_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_overeenkomst_reken .
139            ?eind_overeenkomst_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_overeenkomst_reken .
140            BIND(?eind_overeenkomst_reken - ?start_overeenkomst_reken + 1 AS ?dagen_overeenkomst)
141            
142            BIND (?dagen_overeenkomst/?dagen_periode AS ?factor)
143            
144            # Bereken relevant deel van de omvangwaarde
145            BIND (?factor * ?ptf AS ?omvang_factor_corr)
146        } 
147        GROUP BY ?overeenkomst_afspraak 
148        }
149	}
150}
151